Page 1 of 1
unconditional variance of mgarch-bekk model
Posted: Thu Dec 31, 2009 2:51 am
by luxu1983
dear
how can i to calculate the unconditional variance of two variables mgarch(1,1)-bekk model
thank you very much
Re: unconditional variance of mgarch-bekk model
Posted: Thu Dec 31, 2009 10:24 am
by TomDoan
After a GARCH instruction, the following will work:
Code: Select all
garch(p=1,q=1,mv=bek,method=bfgs,iters=200,pmethod=simplex,piters=20) / xjpn xfra xsui
*
* Size of "C" matrix
*
compute ncomp=%nvar*(%nvar+1)/2
*
* Extract the C, A and B matrix coefficients
*
compute ccoeffs=%xsubvec(%beta,%nregmean+1,%nregmean+ncomp)
compute acoeffs=%xsubvec(%beta,%nregmean+ncomp+1,%nregmean+ncomp+%nvar**2)
compute bcoeffs=%xsubvec(%beta,%nregmean+ncomp+%nvar**2+1,%nregmean+ncomp+2*%nvar**2)
*
* Rearrange the C matrix to a full N x N matrix
*
dec rect cb(%nvar,%nvar)
dec packed cs(%nvar,%nvar)
compute cs=%vectosymm(ccoeffs,%nvar)
ewise cb(i,j)=%if(j<=i,cs(i,j),0.0)
*
* VEC its outer product
*
compute cb=cb*tr(cb)
compute cx=%vec(cb)
*
* The A and B coefficients are saved in the coefficient vector in the transpose of
* the standard internal organization of arrays, so they get transposed after being
* reshaped.
*
compute ab=tr(%reshape(acoeffs,%nvar,%nvar))
compute bb=tr(%reshape(bcoeffs,%nvar,%nvar))
*
* Solve for the unconditional variance. This may not exist as a valid covariance
* matrix if any of the eigenvalues of I-AxA-BxB are negative.
*
compute iab=%identity(%nvar*%nvar)-%kroneker(ab,ab)-%kroneker(bb,bb)
compute h=%reshape(%solve(iab,cx),%nvar,%nvar)
If you've estimated the model using MAXIMIZE, it should be easier, since you will then already have the "AB" and "BB" matrices and will only need to rearrange the C matrix and solve using the last two lines.
Re: unconditional variance of mgarch-bekk model
Posted: Thu Dec 31, 2009 8:11 pm
by luxu1983
luxu1983 wrote:dear
how can i to calculate the unconditional variance of two variables mgarch(1,1)-bekk model
thank you very much
Happy New Year
thank you very much tom
if my model including the asymmetric-term "garch(p=1,q=1,mv=bek,method=bfgs,asy) / x y"
how to calculate the unconditional variance
that is how can i define the new "iab" if the model including the asy-term
Re: unconditional variance of mgarch-bekk model
Posted: Fri Jan 01, 2010 12:19 pm
by TomDoan
There's no closed form solution for the unconditional variance in that case - the expectation of the asymmetry term includes CDF functions involving the variances and covariances.
Re: unconditional variance of mgarch-bekk model
Posted: Fri Jan 01, 2010 7:50 pm
by luxu1983
TomDoan wrote:There's no closed form solution for the unconditional variance in that case - the expectation of the asymmetry term includes CDF functions involving the variances and covariances.
yes
if it is asumed that prob(εt<0)=1/2 and prob(εt>=0)=1/2 for all t
how to calculate the unconditional variance of asy-bekk model
Re: unconditional variance of mgarch-bekk model
Posted: Sat Jan 02, 2010 9:56 am
by TomDoan
The diagonals in Eu(-)u(-)' aren't the problems; it's the off-diagonal terms, which are
integral integal x1 x2 fN(x1,x2|sigma) dx2 dx1
where the two integrals are over -inf to 0. That's a very non-linear function of sigma.
Re: unconditional variance of mgarch-bekk model
Posted: Mon Jan 11, 2010 8:59 am
by luxu1983
TomDoan wrote:The diagonals in Eu(-)u(-)' aren't the problems; it's the off-diagonal terms, which are
integral integal x1 x2 fN(x1,x2|sigma) dx2 dx1
where the two integrals are over -inf to 0. That's a very non-linear function of sigma.
may you provide some program?
Re: unconditional variance of mgarch-bekk model
Posted: Mon Jan 11, 2010 9:30 am
by TomDoan
I don't think there's any direct calculation or even set of implicit equations to solve. However, it can be approximated to any level of desired accuracy by simulation, which is relatively straightforward.