calendar(a) 1960:1
allocate 2017:1

open data WF2016.RAT
data(format=rats)

*print

* EC's starting values
compute phi1=1.4203, phi2=-0.6216, mu=-0.0015, beta0=-0.0339, beta1=0.0560, beta2=-0.0272
compute vtr=1.0, vcyc=0.11, vslo=0.02, vpc=0.0004837

decl frml[rect] af
frml af = ||1.0 ,0.0, 0.0,0.0,1.0|$
            0.0,phi1,phi2,0.0,0.0|$
            0.0, 1.0, 0.0,0.0,0.0|$
            0.0, 0.0, 1.0,0.0,0.0|$
            0.0, 0.0, 0.0,0.0,1.0||

decl frml[vector] zf
frml zf = ||0.0,mu,0.0,0.0,0.0||

decl rect ff
compute ff=||1.0,0.0,0.0|$
				 0.0,1.0,0.0|$
				 0.0,0.0,0.0|$
				 0.0,0.0,0.0|$
				 0.0,0.0,1.0||

decl frml[symmetric] swf
frml swf = ||vtr, 0.0, 0.0|$
				 0.0,vcyc, 0.0|$
				 0.0, 0.0,vslo||

decl frml[rect] cf
frml cf = ||1.0,  0.0|$
				1.0,beta0|$
				0.0,beta1|$
				0.0,beta2|$
				0.0,  0.0||

decl frml[symmetric] svf
frml svf = ||0.0, 0.0|$
				 0.0, vpc||

decl frml[vector] yf
frml yf =||u,ddw||

nonlin(parmset=coeff) phi1 phi2 mu beta0 beta1 beta2
nonlin(parmset=varia) vtr vcyc vslo vpc

dlm(presample=ergodic,parmset=coeff+varia, print,y=tr(yf), a=af, z=zf, f=ff, sw=swf, $
c=cf, sv=svf, type=smooth) 1965:1 2017:1 xstates vstates

set nairu 1965:1 2017:1 = xstates(t)(1)
spgraph(vfields=1,hfields=2,footer="Smoothed Series")
graph(hlabel="Unemployment") 2
# u
# nairu
spgraph(done)