*
* Example 5.4 from pp 234
*
open data ch05_ibmstock_5days.dat
data(format=free,org=columns) 1 3534 dur
*
graph
# dur
*
* WACD model with shape parameter alpha
*
nonlin omega0 gamma1 omega1 alpha
*
set psi = 1.0
frml edur = omega0+gamma1*dur{1}+omega1*psi{1}
*
* eta is the scale parameter to make the mean of the Weibull equal to the new
* value of psi
*
frml logl = (psi=edur),(gma=%lngamma(1+1.0/alpha)),(eta=psi/exp(gma)),$
   log(alpha)+(alpha-1)*log(dur)-alpha*log(eta)-(dur/eta)**alpha
stats dur
compute omega0=%mean,gamma1=omega1=0.0,alpha=1.0
maximize(method=bfgs,iters=500) logl 2 *
*
set normed = dur/psi
spgraph(vfields=2)
graph(header="(a) Adjusted durations")
# dur
graph(header="(b) Normalized durations")
# normed
spgraph(done)
*
* Autocorrelation of the data, and of the data normalized by the model's
* predictions.
*
@regcorrs(number=30) dur
@regcorrs(number=30) normed
*
stats normed 2 3534
stats dur
*
* GACD model with shape parameters alpha and kappa
*
nonlin omega0 gamma1 omega1 alpha kappa
*
* eta is the scale parameter to make the mean of the Weibull
* equal to the new value of psi
*
frml logl = (psi=edur),(lma=%lngamma(kappa+1.0/alpha)-%lngamma(kappa)),(eta=psi/exp(lma)),$
   log(alpha)+(kappa*alpha-1)*log(dur)-kappa*alpha*log(eta)-%lngamma(kappa)-(dur/eta)**alpha
stats dur
compute omega0=%mean,gamma1=omega1=0.0,alpha=1.0,kappa=1.0
maximize(method=bfgs,iters=500) logl 2 *
*
* Same diagnostics as before
*
set normed = dur/psi
@regcorrs(number=30) dur
@regcorrs(number=30) normed