*
* CHAPTER 13
* Page 488
*
open data ch13_star.xls
data(format=xls,org=columns) 1 11598 stark star1 star2 star3 totexpk treadssk tmathssk totexp1 $
  treadss1 tmathss1 totexp2 treadss2 tmathss2 treadss3 tmathss3 totexp3 schidkn schid1n schid2n $
  schid3n tscorek tscore1 tscore2 tscore3 sck sc1 sc2 sc3 rak ra1 ra2 ra3 white black other boy $
  freelunk freelun1 freelun2 freelun3
*
* Table 13.1
*
linreg(robust) tscorek
# sck rak constant
linreg(robust) tscore1
# sc1 ra1 constant
linreg(robust) tscore2
# sc2 ra2 constant
linreg(robust) tscore3
# sc3 ra3 constant
*
* Table 13.2
*
linreg(robust) tscorek
# sck rak constant
linreg(robust) tscorek
# sck rak totexpk constant
*
* The last two columns require a full set of dummies for the school ID The FIX
* function is used to transform the real number %MAXIMUM to the integer value
* required as a DO loop index.
*
ext schidkn
dec vect[series] scdummies(fix(%maximum))
do i=1,fix(%maximum)
   set scdummies(i) = schidkn==i
end do i
*
linreg(robust) tscorek
# sck rak totexpk scdummies
linreg(robust) tscorek
# sck rak totexpk boy freelunk black other scdummies
*
* Table 13.3
* Original estimates standardized by dividing through by the standard deviation
* of the scores. This can be done easily by just dividing each dependent variable
* by the square root of its sample variance.
*
stats(noprint) tscorek
set nscorek = tscorek/sqrt(%variance)
linreg(robust) nscorek
# constant sck rak
*
stats(noprint) tscore1
set nscore1 = tscore1/sqrt(%variance)
linreg(robust) nscore1
# constant sc1 ra1
*
stats(noprint) tscore2
set nscore2 = tscore2/sqrt(%variance)
linreg(robust) nscore2
# constant sc2 ra2
*
stats(noprint) tscore3
set nscore3 = tscore3/sqrt(%variance)
linreg(robust) nscore3
# constant sc3 ra3