*
* Example 21.3 from pp 675-676.
*
open data tablef21-1[1].txt
data(format=prn,org=columns) 1 32 obs gpa tuce psi grade
linreg grade
# constant gpa tuce psi
*
ddv(dist=logit) grade
# constant gpa tuce psi
prj(atmean,dist=logit)
disp "Slope Coefficients for logit"
disp %prjdensity*%beta
*
ddv(dist=probit) grade
# constant gpa tuce psi
prj(atmean,dist=probit)
disp "Slope Coefficients for probit"
disp %prjdensity*%beta
*
ddv(dist=extreme) grade
# constant gpa tuce psi
prj(atmean,dist=extreme)
disp "Slope Coefficients for extreme value"
disp %prjdensity*%beta
*
* Generating predicted probabilities
*
ddv(dist=probit) grade
# constant gpa tuce psi
set gpatest 1 201 = 2+.01*(t-1)
prj(atmean)
do tx=1,201
   prj(xvector=||1.0,gpatest(tx),%meanv(3),0.0||)
   set wopsi tx tx = %prjcdf
   prj(xvector=||1.0,gpatest(tx),%meanv(3),1.0||)
   set withpsi tx tx = %prjcdf
end do t
scatter(style=lines) 2
# gpatest wopsi 1 201
# gpatest withpsi 1 201
*
* Slope coefficient standard errors for probit
*
prj(atmean)
compute delta=%prjdensity*%identity(%nreg)-%prjdensity*%dot(%beta,%meanv)*%beta*tr(%meanv)
compute slopese=%sqrt(%xdiag(delta*%xx*tr(delta)))
*
* Slope coefficient standard errors for logit
*
ddv(dist=logit) grade
# constant gpa tuce psi
prj(atmean,dist=logit)
compute delta=%prjdensity*%identity(%nreg)+%prjdensity*(1-2*%prjcdf)*%beta*tr(%meanv)
compute slopese=%sqrt(%xdiag(delta*%xx*tr(delta)))