*
* Chapter 5. UK data.
*
open data ukdriversksi.txt
calendar(m) 1969
data(format=free,org=columns,skips=1) 1969:01 1984:12 ksi
set logksi = log(ksi)
open data logukpetrolprice.txt
data(format=free,org=columns,skips=1) 1969:01 1984:12 logukpetrol
*
* Fixed coefficients regression done with linreg
*
linreg logksi
# constant logukpetrol
*
compute sigsqeps=%sigmasq,beta=%beta(2)
*
* Model with explanatory variable and deterministic level
*
nonlin sigsqeps sigsqxi=0.0 beta
dlm(a=1.0,c=1.0,sv=sigsqeps,sw=sigsqxi,exact,y=logksi-beta*logukpetrol,$
  method=bfgs,vhat=vhat,svhat=svhat)
*
set resids = %scalar(vhat)/sqrt(%scalar(svhat))
@STAMPDiags(ncorrs=15) resids
dlm(a=1.0,c=1.0,sv=sigsqeps,sw=sigsqxi,exact,y=logksi-beta*logukpetrol,$
  type=smooth) / xstates
set level     = xstates(t)(1)
set levelplus = level+beta*logukpetrol
set irreg     = logksi-levelplus
graph(footer="Figure 5.1 Deterministic level and explanatory variable",$
  key=upright,klabels=||"log UK drivers KSI","deterministic level + beta*log(petrol)"||) 2
# logksi
# levelplus
graph(footer="Figure 5.2 Irregular component for deterministic level + beta * log(petrol)")
# irreg
*
* Same with stochastic level
*
nonlin sigsqeps sigsqxi beta
dlm(a=1.0,c=1.0,sv=sigsqeps,sw=sigsqxi,exact,y=logksi-beta*logukpetrol,$
  method=bfgs,vhat=vhat,svhat=svhat)
*
set resids = %scalar(vhat)/sqrt(%scalar(svhat))
@STAMPDiags(ncorrs=15) resids
dlm(a=1.0,c=1.0,sv=sigsqeps,sw=sigsqxi,exact,y=logksi-beta*logukpetrol,$
  type=smooth) / xstates
set level     = xstates(t)(1)
set levelplus = level+beta*logukpetrol
set irreg     = logksi-levelplus
graph(footer="Figure 5.4 Stochastic level and explanatory variable",$
  key=upright,klabels=||"log UK drivers KSI","deterministic level + beta*log(petrol)"||) 2
# logksi
# levelplus
graph(footer="Figure 5.5 Irregular component for stochastic level + beta * log(petrol)")
# irreg