GARCH with an ARMA mean equation

[Nai_re_PAOK]

Hi there, I am new at RATS, just picked it up two days ago so my question might be naive.

I am trying to estimate a GJR GARCH model with an ARMA structure in the mean equation. I am using the FRML command, but I get an error message that FRML cannot handle MA terms:

## NL4. FRMLs Cannot Have Moving Average Parameters

Is there a way around this? Thanks in advance.

[TomDoan]

Hi there, I am new at RATS, just picked it up two days ago so my question might be naive.

I am trying to estimate a GJR GARCH model with an ARMA structure in the mean equation. I am using the FRML command, but I get an error message that FRML cannot handle MA terms:

## NL4. FRMLs Cannot Have Moving Average Parameters

Is there a way around this? Thanks in advance.

The GJR GARCH model is probably most easily done using the GARCH instruction, and the use of moving average terms for that is covered in the User's Guide in section 9.3.4 (RATS v8) or 12.1.4 (RATS v7). To add those to a FRML definition, you would need to use the lag of whatever series (probably called "u") that you're using for the models residuals.

[Nai_re_PAOK]

Thanks TomDoan, however I am not sure I understand how to add the lags of u in the frml.

The problem I have is that I need to estimate the model through the maximize command because my garch specification is non-standard (it includes two time dummies multiplied with u^2_t-1 and h_t-1). Let me show you what I have

Code: Select all

open data C:\Program Files\Estima\WinRATS 7.2\at.txt
data(format=free,org=columns) 1 287 at

linreg at
# constant at{1}

frml(lastreg,vector=beta) meanf
nonlin(parmset=meanparms) beta
*
set uu = %seesq
set h  = %seesq
set u  = 0.0
*
nonlin(parmset=garchparms) c a b d e f
compute c=%seesq,a=.29,b=.52,d=0.30,e=-0.74,f=0.00001
set dummy = t>=232
frml varf = c+a*uu{1}+b*h{1}+d*uu{1}*dummy{1}+e*h{1}*dummy{1}+f*dummy
frml logl = (u=at-meanf),(uu(t)=u**2),(h(t)=varf(t)),%logdensity(h,u)
maximize(parmset=meanparms+garchparms,METHOD=BHHH,PMETHOD=BHHH) logl 6 *


As you can see the garch specification has two dummies (multiplied with uu and h) that capture any differential effect after a specific date. My question is how to change the mean equation to accommodate an ARMA structure.

Thanks for the help and the patience

[TomDoan]

You need to do the following to define the FRML for the mean equation:

Code: Select all

boxjenk(ar=1,ma=1,const,define=arma11) at / u
modify arma11
vreplace %mvgavge with u
frml(equation=arma11,vector=beta) meanf
nonlin(parmset=meanparms) beta

It's the combination of MODIFY and VREPLACE which substitute out series U for the %MVGAVGE.

[Nai_re_PAOK]

I see. This does it, great! Most obliged TomDoan, thanks.